home *** CD-ROM | disk | FTP | other *** search
/ Nibble Magazine / nib03.dsk / APPLE COMMUNICATOR.int < prev    next >
Text File  |  2023-02-26  |  2KB  |  94 lines
  1. 1 REM  *************************
  2. 2 REM  * APPLE COMMUNICATOR    *
  3. 3 REM  *   BY KEVIN RILEY      *
  4. 4 REM  * COPYRIGHT (C) 1980 BY *
  5. 5 REM  *   MICRO-SPARC, INC    *
  6. 6 REM  *   LINCOLN, MA 01773   *
  7. 7 REM  *************************
  8. 10 REM  *** PUT ALP. ON SCREEN ***
  9. 15 CALL -936:LN=15:SP=1:K=350
  10. 20 DIM ALP$(80)
  11. 25 ALP$="  A  B  C  D  E  F  G  H  I  J  K  L  M  N  O  P  Q  R  S  T  U  V  W  X  Y  Z"
  12. 30 VTAB 2:PRINT ALP$(1,39)
  13. 35 VTAB 5:PRINT ALP$(40,78)
  14. 40 DIM CON$(40)
  15. 45 CON$="SPACE   DELETE   NEW     FAST   SLOW"
  16. 50 VTAB 8:TAB 3:PRINT CON$
  17. 55 REM  *** SCAN ALP ***
  18. 60 FOR X=3 TO 6 STEP 3
  19. 65 FOR Y=3 TO 39 STEP 3
  20. 70 VTAB X:TAB Y: POKE 50,63:PRINT "^": POKE 50,255
  21. 75 FOR TD=0 TO K
  22. 80 IF  PEEK (-16287)>127 THEN GOSUB 500
  23. 85 NEXT TD
  24. 90 VTAB X:TAB Y:PRINT " "
  25. 95 NEXT Y
  26. 100 NEXT X
  27. 105 FOR Z=5 TO 38 STEP 8
  28. 110 VTAB 9:TAB Z: POKE 50,63:PRINT "^": POKE 50,255
  29. 115 FOR TD=0 TO K
  30. 120 IF  PEEK (-16287)>127 THEN GOSUB Z*200
  31. 125 NEXT TD
  32. 130 VTAB 9:TAB Z:PRINT " "
  33. 135 NEXT Z
  34. 140 GOTO 60
  35. 500 REM  *** PRINT ALP ON SCREEN ***
  36. 501 IF (LN=23) AND (SP=35) THEN 580
  37. 505 A=Y
  38. 510 IF X=6 THEN A=A+39
  39. 515 VTAB LN:TAB SP:PRINT ALP$(A,A)
  40. 520 SP=SP+1
  41. 525 IF SP=40 THEN LN=LN+1
  42. 530 IF SP=40 THEN SP=1
  43. 535 IF LN#23 THEN 565
  44. 540 VTAB LN:TAB 37: POKE 50,63
  45. 545 PRINT "END"
  46. 550 FOR T=0 TO 500:NEXT T
  47. 555 VTAB LN:TAB 37: POKE 50,255
  48. 560 PRINT "   "
  49. 565 IF  PEEK (-16287)<127 THEN 575
  50. 570 GOTO 565
  51. 575 RETURN 
  52. 580 VTAB 12:TAB 16: POKE 50,63
  53. 585 PRINT "PLEASE KEY IN NEW"
  54. 586 FOR T=0 TO 500:NEXT T
  55. 590  POKE 50,255:RETURN 
  56. 1000 REM  *** MAKE A SPACE ***
  57. 1010 VTAB LN:TAB SP
  58. 1020  POKE 50,63:PRINT " "
  59. 1030 FOR TM=0 TO 250:NEXT TM
  60. 1040 VTAB LN:TAB SP: POKE 50,255:PRINT " "
  61. 1050 SP=SP+1
  62. 1055 IF  PEEK (-16287)<127 THEN 1060
  63. 1058 GOTO 1055
  64. 1060 RETURN 
  65. 2600 REM  *** DELETE ***
  66. 2610 SP=SP-1
  67. 2620 IF SP<1 THEN SP=1
  68. 2630 VTAB LN:TAB SP
  69. 2640 PRINT " "
  70. 2650 IF  PEEK (-16287)<127 THEN 2670
  71. 2660 GOTO 2650
  72. 2670 RETURN 
  73. 4200 REM  *** NEW ***
  74. 4210  POKE 34,11
  75. 4220 CALL -936
  76. 4230  POKE 34,0
  77. 4240 LN=15:SP=1
  78. 4250 RETURN 
  79. 5800 REM  *** FAST ***
  80. 5810 K=K-25
  81. 5820 IF K>75 THEN 5860
  82. 5830 VTAB 12:TAB 10: POKE 50,63:PRINT "YOU ARE AT TOP SPEED": POKE 50,255
  83. 5840 FOR T=0 TO 1000:NEXT T
  84. 5850 VTAB 12:TAB 10:PRINT "                    "
  85. 5860 IF K<75 THEN K=75
  86. 5870 IF  PEEK (-16287)<127 THEN 5890
  87. 5880 GOTO 5870
  88. 5890 RETURN 
  89. 7400 REM  *** SLOW ***
  90. 7410 K=K+25
  91. 7420 IF  PEEK (-16287)<127 THEN 7440
  92. 7430 GOTO 7420
  93. 7440 RETURN 
  94.